易读小说下载

@echo off
:开始
color 02
title 易读下载器
echo ------易读网小说下载器------
echo 格式：http://www.yi-look.com/art_7826_3170.html
echo 在下面粘贴如上所示[小说目录网址]并回车
set/p 小说网址=:
:获取下载列表
cls
title 易读下载器 正在获取下载列表
echo 正在获取下载列表..
::取得目录html和txt文件名
for /f "tokens=3 delims=/" %%i in ("%小说网址%") do (
set "html目录文件=%%i"
set "txt目录文件=%%~ni.txt"
)
tools\curl -s %小说网址% >"目录文件\%html目录文件%"
if not exist "目录文件\%html目录文件%" echo 下载目录出错！& pause & goto :eof
tools\htox32c /IP /O0 /U1+4 "目录文件\%html目录文件%" >nul 2>nul
::取得小说名
for /f "tokens=1 delims=<" %%i in ('type "目录文件\%txt目录文件%" ^|find "作者:"') do set "小说名字=%%i"
::是否连载归类
for /f "tokens=3 delims=:" %%i in ('type "目录文件\%txt目录文件%" ^|find "作者:"') do (
for /f %%j in ('echo %%i') do  set "小说名字+=%%j\%小说名字%"
)
for /f "tokens=3 delims=:" %%i in ('type "目录文件\%txt目录文件%" ^|find "作者:"') do (
for /f "tokens=2 delims=[]" %%j in ('echo %%i') do set "小说名字++=%%j\%小说名字+%"
)
md "小说文件\%小说名字++%\网页单章" "小说文件\%小说名字++%\文本单章" >nul 2>nul
cls
:下载
del/q "目录文件\%小说名字%.txt" >nul 2>nul
::生成下载列表
for /f "tokens=1,2 delims=<'" %%a in ('type "目录文件\%txt目录文件%" ^|find /i "节<'read"') do call :生成下载列表 %%a %%b
::取得下载文件数目
for /f %%a in ('tools\wc.exe -l "目录文件\%小说名字%.txt"') do set "下载文件数=%%a"
::联系章节名和章节网址
for /f "tokens=1,2 delims=|" %%a in ('type "目录文件\%小说名字%.txt"') do set "the_%%a=%%b"
cls
echo 正在下载..
for /l %%i in (1 1 %下载文件数%) do call :开始下载 %%i
copy /y tools\htox32c.exe %windir%\
pushd "小说文件\%小说名字++%\网页单章\"
htox32c /IP /O0 /U1+4 * >nul 2>nul
popd
move "小说文件\%小说名字++%\网页单章\*.txt" "小说文件\%小说名字++%\文本单章\" >nul 2>nul
>"小说文件\%小说名字++%\%小说名字%.txt" echo "%小说名字%"
cls
title 易读下载器 正在合并 %小说名字%
echo 正在合并..
for /l %%i in (1 1 %最后一章%) do (
>"小说文件\%小说名字++%\文本单章\%%i.txt" echo 　　第%%i节
call :文本处理 %%i
>>"小说文件\%小说名字++%\%小说名字%.txt" type "小说文件\%小说名字++%\文本单章\%%i.txt"
)
call :清除临时文件
cls
title 易读下载器 下载完毕
echo 完毕..
echo 最后一章:第%最后一章%章
ping 127.1 >nul 2>nul
goto :eof
:生成下载列表
set "章节序号=%1"
set "章节序号=%章节序号:*第=%"
set "章节序号=%章节序号:~0,-1%"
set "最后一章=%章节序号%"
>>"目录文件\%小说名字%.txt" echo %章节序号%^|http://www.yi-look.com/%2
goto :eof
:开始下载
set "章节序号=%1"
set/a 进度=%章节序号%*100/%最后一章%
title %进度%%% 正在下载 %小说名字%
call tools\curl -s %%the_%章节序号%%% >"小说文件\%小说名字++%\网页单章\chap_%章节序号%.html"
goto :eof
:文本处理
for /f %%a in ('tools\wc.exe -l "小说文件\%小说名字++%\文本单章\chap_%1.txt"') do set "总的行数=%%a"
set "干掉头部行数=8"
set "干掉尾部行数=8"
set/a 下上行数=%总的行数%-%干掉头部行数%
set/a 上下行数=%下上行数%-%干掉尾部行数%
type "小说文件\%小说名字++%\文本单章\chap_%1.txt" | tools\LineX.exe -t %下上行数% | tools\LineX.exe -h %上下行数% >>"小说文件\%小说名字++%\文本单章\%1.txt"
goto :eof
:清除临时文件
del/q "目录文件\%txt目录文件%" >nul 2>nul
del/q "目录文件\%html目录文件%" >nul 2>nul
del/q "小说文件\%小说名字++%\文本单章\chap_*.txt" >nul 2>nul
goto :eof